ESMF_HConfigMatch Function

  function ESMF_HConfigMatch(hconfig1, hconfig2, keywordEnforcer, rc)
!
! !RETURN VALUE:
    type(ESMF_HConfigMatch_Flag) :: ESMF_HConfigMatch

! !ARGUMENTS:
    type(ESMF_HConfig),  intent(in)             :: hconfig1
    type(ESMF_HConfig),  intent(in)             :: hconfig2
type(ESMF_KeywordEnforcer), optional:: keywordEnforcer ! must use keywords below
    integer,              intent(out), optional :: rc
!
! !DESCRIPTION:
!   \label{HConfigMatch}
!   Determine the level to which {\tt hconfig1} and {\tt hconfig2} match.
!
!   Returns a value of type {\tt ESMF\_HConfigMatch\_Flag},
!   indicating how closely the two HConfig objects match. For a description of
!   the possible return values, see~\ref{const:hconfigmatch}.
!   Note that this call only performs PET local matching. Different match values
!   may be returned on different PETs for the same HConfig pair.
!
!   The arguments are:
!   \begin{description}
!   \item[hconfig1]
!     {\tt ESMF\_HConfig} object.
!   \item[hconfig2]
!     {\tt ESMF\_HConfig} object.
!   \item[{[rc]}]
!     Return code; equals {\tt ESMF\_SUCCESS} if there are no errors.
!   \end{description}
!
!EOP
!------------------------------------------------------------------------------
    integer                       :: localrc      ! local return code
    type(ESMF_HConfigMatch_Flag)  :: matchResult

    ! initialize return code; assume routine not implemented
    localrc = ESMF_RC_NOT_IMPL
    if (present(rc)) rc = ESMF_RC_NOT_IMPL

    ! Initialize return value to invalid, in case of bail-out
    ESMF_HConfigMatch = ESMF_HCONFIGMATCH_INVALID

    ! Check init status of arguments
    ESMF_INIT_CHECK_DEEP(ESMF_HConfigGetInit, hconfig1, rc)
    ESMF_INIT_CHECK_DEEP(ESMF_HConfigGetInit, hconfig2, rc)

    ! Call into the C++ interface, which will sort out optional arguments.
    call c_ESMC_HConfigMatch(hconfig1, hconfig2, matchResult, localrc)
    if (ESMF_LogFoundError(localrc, ESMF_ERR_PASSTHRU, &
      ESMF_CONTEXT, rcToReturn=rc)) return

    ! Set the actual return value
    ESMF_HConfigMatch = matchResult

    ! return successfully
    if (present(rc)) rc = ESMF_SUCCESS

  end function ESMF_HConfigMatch