Advertise Subroutine

private subroutine Advertise(xdata, rc)

Arguments

Type IntentOptional Attributes Name
type(ESMF_GridComp) :: xdata
integer, intent(out) :: rc

Calls

proc~~advertise~~CallsGraph proc~advertise Advertise interface~esmf_gridcompgetinternalstate ESMF_GridCompGetInternalState proc~advertise->interface~esmf_gridcompgetinternalstate interface~nuopc_advertise NUOPC_Advertise proc~advertise->interface~nuopc_advertise interface~nuopc_compget NUOPC_CompGet proc~advertise->interface~nuopc_compget proc~esmf_logfounderror ESMF_LogFoundError proc~advertise->proc~esmf_logfounderror proc~esmf_logseterror ESMF_LogSetError proc~advertise->proc~esmf_logseterror proc~nuopc_modelget NUOPC_ModelGet proc~advertise->proc~nuopc_modelget proc~x_comp_get_config x_comp_get_config proc~advertise->proc~x_comp_get_config proc~nuopc_advertisefield NUOPC_AdvertiseField interface~nuopc_advertise->proc~nuopc_advertisefield proc~nuopc_advertisefields NUOPC_AdvertiseFields interface~nuopc_advertise->proc~nuopc_advertisefields proc~nuopc_cplcompget NUOPC_CplCompGet interface~nuopc_compget->proc~nuopc_cplcompget proc~nuopc_gridcompget NUOPC_GridCompGet interface~nuopc_compget->proc~nuopc_gridcompget esmf_breakpoint esmf_breakpoint proc~esmf_logfounderror->esmf_breakpoint proc~esmf_logrc2msg ESMF_LogRc2Msg proc~esmf_logfounderror->proc~esmf_logrc2msg proc~esmf_logwrite ESMF_LogWrite proc~esmf_logfounderror->proc~esmf_logwrite proc~esmf_logseterror->esmf_breakpoint proc~esmf_logseterror->proc~esmf_logrc2msg proc~esmf_logseterror->proc~esmf_logwrite proc~nuopc_modelget->interface~nuopc_compget proc~nuopc_modelget->proc~esmf_logfounderror proc~nuopc_modelbaseget NUOPC_ModelBaseGet proc~nuopc_modelget->proc~nuopc_modelbaseget proc~x_comp_get_config->proc~esmf_logfounderror proc~x_comp_get_config->proc~esmf_logseterror esmf_hconfigcreateat esmf_hconfigcreateat proc~x_comp_get_config->esmf_hconfigcreateat esmf_hconfigisdefined esmf_hconfigisdefined proc~x_comp_get_config->esmf_hconfigisdefined proc~esmf_gridcompget ESMF_GridCompGet proc~x_comp_get_config->proc~esmf_gridcompget proc~esmf_hconfigdestroy ESMF_HConfigDestroy proc~x_comp_get_config->proc~esmf_hconfigdestroy proc~x_comp_read_fields x_comp_read_fields proc~x_comp_get_config->proc~x_comp_read_fields proc~x_comp_read_geom x_comp_read_geom proc~x_comp_get_config->proc~x_comp_read_geom proc~x_comp_read_output x_comp_read_output proc~x_comp_get_config->proc~x_comp_read_output

Source Code

  subroutine Advertise(xdata, rc)
    ! arguments
    type(ESMF_GridComp)  :: xdata
    integer, intent(out) :: rc
    ! local variables
    integer                    :: stat
    type(xstate_wrap)          :: is
    type(ESMF_State)           :: importState, exportState
    type(xdata_state), pointer :: xstate
    type(xdata_field), pointer :: xfield => null()

    rc = ESMF_SUCCESS

    ! query component for internal state
    nullify(is%ptr)
    call ESMF_GridCompGetInternalState(xdata, is, rc)
    if (ESMF_LogFoundError(rcToCheck=rc, msg=ESMF_LOGERR_PASSTHRU, &
      line=__LINE__, file=__FILE__)) return
    xstate => is%ptr
    if (.not. associated(xstate)) then
      call ESMF_LogSetError(ESMF_RC_PTR_NOTALLOC, &
        msg='XDATA: xstate has not been associated', &
        line=__LINE__, file=__FILE__, rcToReturn=rc)
      return
    endif

    ! get configuration information
    call x_comp_get_config(xdata, xstate, rc=rc)
    if (ESMF_LogFoundError(rcToCheck=rc, msg=ESMF_LOGERR_PASSTHRU, &
      line=__LINE__, file=__FILE__)) return

    ! query component for information
    call NUOPC_CompGet(xdata, name=xstate%cname, &
      verbosity=xstate%verbosity, diagnostic=xstate%diagnostic, rc=rc)
    if (ESMF_LogFoundError(rcToCheck=rc, msg=ESMF_LOGERR_PASSTHRU, &
      line=__LINE__, file=__FILE__)) return

    ! query for importState and exportState
    call NUOPC_ModelGet(xdata, importState=importState, &
      exportState=exportState, rc=rc)
    if (ESMF_LogFoundError(rcToCheck=rc, msg=ESMF_LOGERR_PASSTHRU, &
      line=__LINE__, file=__FILE__)) return

    ! advertise import fields
    xfield => xstate%imp_flds_head
    do while (associated(xfield))
      call NUOPC_Advertise(importState, xfield%stdn, rc=rc)
      if (ESMF_LogFoundError(rcToCheck=rc, msg=ESMF_LOGERR_PASSTHRU, &
        line=__LINE__, file=__FILE__)) return
      xfield => xfield%nfld
    enddo

    ! advertise export fields
    xfield => xstate%exp_flds_head
    do while (associated(xfield))
      call NUOPC_Advertise(exportState, xfield%stdn, rc=rc)
      if (ESMF_LogFoundError(rcToCheck=rc, msg=ESMF_LOGERR_PASSTHRU, &
        line=__LINE__, file=__FILE__)) return
      xfield => xfield%nfld
    enddo
  endsubroutine Advertise